**Graphs made easy using SAS Graph Template Language**

**Manohar Modem, Cytel Inc**

**Bhavana Bommisetty, Vita Data Sciences**

**Summary**

Creating SAS graphs needs us to look at various elements involved in a graph. It is quite simple to find descriptive statistics using SAS procedures like proc freq/proc means as the number of SAS statements and options required is very few and can be easily remembered. But, sas graph procedures has many statements and many more options. So, it isn’t easy to remember all of these statements and options and when to use them correctly. So, we need to a have an specific approach on how to create SAS graphs. This paper demonstrates how to do various clinical graphs using GTL. Besides providing GTL code and graphs, we have also provided simple dummy data that was used to create these graphs. This is to encourage the programmer to generate these graphs by themselves.

We use two procedures to create graphs in GTL.

1. Proc template

2. Proc sgrender

By itself, Proc template doesn’t create the graph. It creates a template and we apply this template to the data using Proc sgrender.

Here is the basic code that is needed in writing GTL code:

**proc** **template**;

define statgraph *template-name*;

begingraph;

endgraph;

end;

**run**;

**proc** **sgrender** data= template= *template-name*;

**run**;

These are common elements in a SAS graph:

Let’s go from outward to inward.

|  |  |  |
| --- | --- | --- |
|  | **Element** | **GTL statement** |
| 1 | Title | Entrytitle |
| 2 | Footnote | Entryfoonote |
| 3 | Axes | Xaxisopts; Yaxisopts |
| 4 | Plot | Depends on the graph. Eg: scatterplot |
| 5 | Legend | Discretelegend |

Let’s expand basic proc template code using these common elements GTL statements

proc template;

define statgraph template-name;

begingraph;

entrytitle;

entryfootnote;

layout overlay/xaxisopts yaxisopts;

scatterplot x=*xvar* y=*yvar* name='scat'; /\*example for a plot\*/

discretelegend 'scat' /location= inside;

endlayout;

endgraph;


end;

run;

So, now we have the required code to create a GTL graph. Let’s jump right into creating graphs using simple dummy data. We will discuss various concepts and tecnhiques in creating simple and complex graphs.

In the final paper, we are going to explain how we utilized various features of GTL in creating the following graphs. Also, we are going to provide dummy data for and GTL code for the plots in GitHub repository as it is going to be overwhelming to keep all dummy data in the paper itself.

**1. Scatter plot**



**proc** **template**;

define statgraph scat;

begingraph;

entrytitle "Systolic BP over time" ;

entryfootnote halign=left " Note: Systolic BP >120mmHg indicates elevated BP";

layout overlay/ xaxisopts=(offsetmin=**0.1** offsetmax=**0.2**)

yaxisopts=(offsetmin=**0.1** offsetmax=**0.3**);

scatterplot x=ady y=systolic/group= trtn name= 'treatment' /\*datalabel=subject\*/ ;

referenceline y=**120** / lineattrs=(pattern=shortdash ) ;

discretelegend 'treatment' / location= inside halign=right valign=top border=yes;

endlayout;

endgraph;

end;

**run**;

options orientation=landscape ;

ods listing close;

ODS RTF FILE="&gpathname./scatter..rtf" ;

ods graphics on/reset=all height=**5.5**in width=**6.5**in imagename="scatter" imagefmt=png noborder ;

**proc** **sgrender** data=heart2 template=scat;


format trtn trt.;

**run**;

ods \_all\_ close;

ods listing;

**2. Histogram**



ods path show;

ods path work.testtemp(update) sashelp.tmplmst(read);

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

**proc** **template**;

define statgraph histogram/store=work.testtemp;

begingraph;

entrytitle textattrs=(size=**11**pt weight=bold) halign = center 'Histogram for systolic BP';

layout overlay/ xaxisopts=(offsetmin=**0.05** linearopts=(viewmin=**50** viewmax=**350**) display= (ticks tickvalues))

Yaxisopts=(offsetmax=**0.05** linearopts=(viewmin=**0** viewmax=**1000**) label= "Frequency" display= (ticks tickvalues label));

histogram systolic/ scale=count binwidth= **7** fillattrs=(color=CX8A2BE2 transparency=**0.3** ) ;


endlayout;

endgraph;

end;

**run**;

**3. Line plot with error bars**



**proc** **template**;

define statgraph mean\_se;

begingraph;

entrytitle textattrs=(size=**12**pt weight=normal) halign = center 'Coagulation (mean +/- SE) values by visit';

entryfootnote textattrs=(size=**9**pt weight=normal) halign=left "pathaname/programname" halign= right "Data as of: date" halign=right "Run date: &sysdate9.";

layout overlay/xaxisopts=(offsetmin=**0.05** offsetmax=**0.05** linearopts=(tickvaluelist= (**0** **4** **8** **12**)) label= 'Time (weeks)')

yaxisopts=(griddisplay=on gridattrs=(thickness= **0.1** color=lightgrey) linearopts=(tickvaluepriority=true TICKVALUESEQUENCE=(START=**12** END=**16** INCREMENT=**1**)) offsetmin=**0.15** offsetmax=**0.1** label='Mean (SE+/-)');

seriesplot x= avisitn2 y= mean /group =treatn name= 'trt' ;

scatterplot x=avisitn2 y=mean/ group=treatn yerrorlower= minus\_se yerrorupper=plus\_se markerattrs=(symbol= graphdata4)

datalabel= mean datalabelattrs=(color=brown);

drawtext textattrs=(size=**9**pt) "Number of Subjects" /anchor=bottomleft width=**22** widthunit=percent

xspace=wallpercent yspace=wallpercent x=**1** y=**11** justify=center ;

innermargin/align=bottom pad=**0.8**;

axistable x=avisitn value=nsubj / class=treatn ;

endinnermargin;

discretelegend 'trt' / title= " " titleattrs= (size=**9**pt weight=normal ) location= inside halign=left valign=top

valueattrs= (size=**9**pt) border=false;


endlayout;

endgraph;

end;

**run**;

**4. Forest plot**



**proc** **template**;

define statgraph forest;

begingraph;

entrytitle textattrs=(size=**10.9**pt weight=bold) halign = left "Forest plot of ABC parameter adjusted mean change from baseline versus placebo at Week 40" ;

entryfootnote textattrs=(size=**8.5**pt weight=normal) halign = left "NOTE: Results were based on an MMRM model" ;

layout overlay /walldisplay= none xaxisopts=(label="Adjusted mean change vs placebo (95% CI)" offsetmin= **0.05** offsetmax=**0.05** display= (label tickvalues line)

linearopts=(tickvaluepriority=true tickvaluesequence=(start=-**1.5** end=**1.5** increment=**0.5**)))

yaxisopts=(offsetmin=**0.25** offsetmax=**0.33** display= (tickvalues line) discreteopts=(colorbands=even COLORBANDSATTRS=(color=burlywood)));

scatterplot x=df\_amean y=label / legendlabel="Active drug" name= "trt" ERRORBARCAPSHAPE= NONE

xerrorlower=LCL xerrorupper=UCL errorbarattrs=(color=blue) markerattrs=(symbol=circlefilled size=**8** color=blue );

referenceline x=**0** / lineattrs= ( pattern=**2**) ;

innermargin /align=right;

axistable y=start value=pdecl / valueattrs=(size=**10**) display=(values);

axistable y=start value=empty / valueattrs=(size=**10** ) display=(values) DATATRANSPARENCY =**1**;

axistable y=start value=df\_amean / valueattrs=(size=**10**) display=(values) ;

endinnermargin;

drawtext textattrs=( size=**9**pt) "Favors Active" /anchor=bottomleft width=**18** widthunit=percent

xspace=wallpercent yspace=wallpercent x=**18** y=**3.5** justify=center ;

drawtext textattrs=( size=**9**pt) "Favors Placebo" /anchor=bottomleft width=**18** widthunit=percent

xspace=wallpercent yspace=wallpercent x=**50** y=**3.5** justify=center ;

drawtext textattrs=( size=**9**pt) "No. of subjects" /anchor=bottomleft width=**18** widthunit=percent

xspace=wallpercent yspace=wallpercent x=-**17** y=**80** justify=center ;

drawtext textattrs=( size=**9**pt) "Placebo, Active" /anchor=bottomleft width=**35** widthunit=percent

xspace=wallpercent yspace=wallpercent x=-**18** y=**75** justify=center ;

drawtext textattrs=( size=**9**pt) "Placebo decline" /anchor=bottomleft width=**10** widthunit=percent

xspace=wallpercent yspace=wallpercent x=**74** y=**80** justify=center ;

drawtext textattrs=( size=**9**pt) "Adjusted mean change vs placebo" /anchor=bottomleft width=**12** widthunit=percent

xspace=wallpercent yspace=wallpercent x=**90** y=**80** justify=left;

discretelegend 'trt' /pad=(left=**15** ) LOCATION=INSIDE HALIGN=LEFT VALIGN= TOP border=true;


endlayout;

endgraph;

end;

**run**;

**5. Barchart (Panel)**



**proc** **template**;

define statgraph panelchart;

begingraph;

discreteattrmap name='Sev';

value 'None' / fillattrs= (color=grey transparency=**0.5**) lineattrs=(color=white);

value 'Mild' / fillattrs= (color= Orange transparency=**0.7**) lineattrs=(color=white);

value 'Moderate' / fillattrs= (color= Orange transparency=**0**) lineattrs=(color=white);

value 'Severe' / fillattrs= (color= maroon transparency=**0.3**) lineattrs=(color=white);

value 'Extreme' / fillattrs= (color= red transparency=**0**) lineattrs=(color=white);

enddiscreteattrmap;

discreteattrvar attrvar=max\_sev\_map var=aesevc attrmap='Sev';

entrytitle 'Incidence of rash AE severity scores by week for the first 4 weeks';

layout datapanel classvars=(avisitn) / headerlabeldisplay= value columns=**2** columngutter=**2** rowgutter=**2** columndatarange=union columnweight=proportional

columnaxisopts=(label = "Treatment" tickvalueattrs=(size=**9**) )

rowaxisopts=(display= (label ticks tickvalues) offsetmin=**0**

label = "Number of Subjects with Incidence " tickvalueattrs=(size=**9**));

layout prototype;

barchart x=trt y=nsubj2/ group=max\_sev\_map name='bar' groupdisplay =cluster grouporder=data;

innermargin/align=top;

axistable x=trt value=nsubj / display=(values);

endinnermargin;

endlayout;

sidebar ;

discretelegend 'bar' / title= "Severity";

Endsidebar;



endlayout;

endgraph;

end;

**run**;

**6. Box plot (Custom panel)**



**proc** **template**;

define statgraph box\_panel;

dynamic \_BYVAL\_ \_ylabel \_ticks;

begingraph;

discreteattrmap name='Sex';

value 'Female' /markerattrs=(color=black) textattrs= (color=green) fillattrs= (color=green transparency=**0.4**) lineattrs=(color=black);

value 'Male' / markerattrs=(color=black) textattrs= (color=red ) fillattrs= (color= red transparency=**0.4**) lineattrs=(color=black);

enddiscreteattrmap;

discreteattrvar attrvar=sex\_map1 var=sex\_a1 attrmap='Sex';

discreteattrvar attrvar=sex\_map2 var=sex\_a2 attrmap='Sex';

entrytitle textattrs=(size=**11**pt weight=bold ) halign = center 'Boxplot ';

entrytitle textattrs=(size=**11**pt weight=bold) halign = center \_BYVAL\_;

entryfootnote textattrs=(size=**9**pt weight=normal) halign=left "Source: %upcase(&AUTOSOURCEPATH..sas)" halign=right "Run date: &sysdate9.";

layout lattice / columns=**2** rows=**2** columndatarange=unionall rowdatarange=unionall rowweights= (**0.9** **0.1**) columnweights=(**0.5** **0.5**);

rowaxes;

rowaxis / offsetmin=**0.1** offsetmax=**0.1** griddisplay=on display=(ticks tickvalues label) label=\_ylabel type=linear

linearopts=(tickvaluelist=\_ticks tickvaluepriority=true) ;

rowaxis / display=none ;

endrowaxes;

column2headers;

entry textattrs=graphlabeltext(weight=normal) 'STUDY: A001';

entry textattrs=graphlabeltext(weight=normal) 'STUDY: A002';

endcolumn2headers;

layout overlay / xaxisopts=(display=(ticks tickvalues))

x2axisopts=(display=(label) );

boxplot x=race\_a1 y=aval\_a1/group=sex\_map1 groupdisplay=cluster ;

endlayout;

layout overlay / xaxisopts=(display=(ticks tickvalues)) ;

boxplot x=race\_a2 y=aval\_a2 /group=sex\_map2 groupdisplay=cluster;

endlayout;

Layout Overlay / walldisplay=none xaxisopts=(display=none griddisplay=off displaySecondary=none)

x2axisopts=(display=none griddisplay=off displaySecondary=none);

AxisTable Value=nsubj\_a1 X=race\_a1 /class=sex\_a1 labelPosition=min ValueAttrs=(size=**9** ) Display=(Label );

endlayout;

Layout Overlay / walldisplay=none xaxisopts=(display=none griddisplay=off displaySecondary=none)

x2axisopts=(display=none griddisplay=off displaySecondary=none);

AxisTable Value=nsubj\_a2 X=race\_a2/class=sex\_a2 labelposition=max labelattrs= (color=white size=**0**) ValueAttrs=(size=**9** );

endlayout;

endlayout;

endgraph;

end;

**run**;

ods listing close;

**%macro** ***boxp***;

ods rtf file="&gpathname/boxpanel..rtf" ;

options orientation=landscape ;

%do i = **1** %to **2**;

ods graphics on/reset=all height=**6.5**in width=**8.5**in imagename="boxpanel" imagefmt=png noborder;

proc sgrender data=boxd5 template=box\_panel;

dynamic %if &i=**1** %then %do;

%str(\_ylabel= "Systolic BP in mmHg")

%str(\_ticks="**100** **120** **140** **160** ");

%end;

%else %if &i=**2** %then %do;

%str(\_ylabel= "Diastolic BP in mmHg")

%str(\_ticks="**60** **80** **100** **120** ");

%end;

format pg byval.;

where pg = &i;

by pg;

run;

%end;


**%mend**;

%***boxp***

ods \_all\_ close;

ods listing;

**7. Waterfall plot**



**proc** **template**;

define statgraph waterfall;

begingraph;

entrytitle "Best % change in tumor size from baseline";

symbolchar name=rightarrow char='2192'x;

layout overlay/xaxisopts=( label = "Subject" type=discrete)

yaxisopts =(label = "Best % change in tumor size from baseline" LINEAROPTS=(tickvaluesequence=(start=-**100** end=**100** increment=**20**) viewmin = -**120** viewmax = **100** ));

referenceline y=**20** / lineattrs=(thickness=**1.5**);

referenceline y=-**30** / lineattrs=(thickness=**1.5**);

barchart x=subjid y=pchg/ group=response barlabelattrs=(size=**6**pt) barwidth=**0.25** name="BAR";

scatterplot x=subjid y=marker / markerattrs=(symbol=rightarrow color=black size=**30** weight=bold);

discreteLegend "BAR"/ across=**2** autoalign=(topright) location=inside titleattrs=(size=**10**pt)

valueattrs=(size=**8**pt) border=true borderattrs=(color=black) title="Response";

drawtext textattrs=(size=**15**pt color=black weight=bold) {unicode "2192"x} / anchor=bottomright width=**9** widthunit=percent xspace=wallpercent yspace=wallpercent x=**86** y=**4.75** justify=center ;

drawtext textattrs=(size=**8**pt) "Ongoing" / anchor=bottomright width=**12** widthunit=percent xspace=wallpercent yspace=wallpercent x=**95** y=**5.35** justify=center ;


endlayout;

endgraph;

end;

**run**;

**8. Spider plot**



**proc** **template**;

define statgraph spider;

begingraph;

discreteattrmap name='criteria';

value 'Progressive Disease' / lineattrs=(color=red) markerattrs=(color=red);

value 'Complete Response' / lineattrs=(color=green) markerattrs=(color=green);

value 'Partial Response' / lineattrs=(color=yellow) markerattrs=(color=yellow);

value 'Stable Disease' / lineattrs=(color=blue) markerattrs=(color=blue);

enddiscreteattrmap;

discreteattrvar attrvar=resn\_map var=response attrmap='criteria';

layout overlay / xaxisopts=(label='Duration in Weeks' linearopts=(tickvaluesequence=(start=**0** end=**20** increment=**4**)

viewmin=**0** viewmax=**20**) offsetmin=**0.1**)

yaxisopts=(label='% Change in Tumor Size from Baseline'

linearopts=(tickvaluepriority=true tickvaluesequence=(start=-**100** end=**100** increment=**20**)));

referenceline y=**0**/ lineattrs=(thickness=**1.5**);

referenceline y=**20**/ lineattrs=(thickness=**1**);

referenceline y=-**30**/ lineattrs=(thickness=**1**);

seriesplot x=avisitn y=pchg/group=id linecolorgroup=resn\_map

lineattrs=(thickness=**2** pattern=solid) groupdisplay=overlay break=true;

scatterplot x=avisitn y=pchg/ group=resn\_map markerattrs=(size=**6** symbol=squarefilled) groupdisplay=overlay name='a';

discretelegend "a"/ valign=bottom across=**2**;

endlayout;

endgraph;

end;

**run**;

**9. KM plot**

**10. Swimmer plot**